home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1990: Discy Business / Discy Business.2mg / DEV.CD / GUIDED.TOURS / IIC.PLUS.TOUR / INSIDE.STORY / MENU (.txt) < prev    next >
Encoding:
Applesoft BASIC Source Code  |  1989-03-20  |  2.9 KB  |  79 lines  |  [FC] Applesoft BASIC Program (0x0801)
  1. 0  ONERR  GOTO 10000
  2. 1 CL$ =  CHR$(12): HOME : TEXT : PRINT CL$:KS% =  -16384:KC% =  -16368:D$ =  CHR$(4): DIM MENU$(12)
  3. 2  POKE 4113,20: CALL 4096
  4. 9  POKE 230,32: HCOLOR= 0: HPLOT 0,0: CALL 62454
  5. 10  HCOLOR= 3: FOR I = 0 TO 2: HPLOT 0 +I,0 +I TO 279 -I,0 +I TO 279 -I,191 -I TO 0 +I,191 -I TO 0 +I,0 +I: NEXT I
  6. 20  FOR I = 0 TO 1: HPLOT 50 +I,10 +I TO 222 -I,10 +I TO 222 -I,28 -I TO 50 +I,28 -I TO 50 +I,10 +I: NEXT I
  7. 30  HPLOT 0,36 TO 279,36
  8. 40  HPLOT 0,172 TO 279,172
  9. 79  REM <CTRL-0x0a><CTRL-0x0a>** Print Header **<CTRL-0x0a>
  10. 80  VTAB 3:S$ = "The Inside Story Menu": GOSUB 100
  11. 90  GOTO 900
  12. 99  REM <CTRL-0x0a><CTRL-0x0a>** Center String **<CTRL-0x0a>
  13. 100  HTAB 21 - LEN(S$)/2: PRINT S$: RETURN 
  14. 109  REM <CTRL-0x0a><CTRL-0x0a>** Print Menu Item **<CTRL-0x0a>
  15. 110  VTAB 7 +V%: HTAB 6: PRINT S$: RETURN 
  16. 199  REM <CTRL-0x0a><CTRL-0x0a>** Check for RETURN **<CTRL-0x0a>
  17. 200  IF  PEEK(KS%) < >141  THEN 200
  18. 210  POKE KC%,0: RETURN 
  19. 899  REM <CTRL-0x0a><CTRL-0x0a>** Display Options **<CTRL-0x0a>
  20. 900  FOR I = 0 TO 11: READ MENU$(I): NEXT I
  21. 910  FOR I = 0 TO 5: VTAB 7 +2 *I: HTAB 4: IF  PEEK(791 +I) >0  THEN  PRINT "*";
  22. 915  HTAB 6: PRINT MENU$(2 *I): NEXT I
  23. 920  VTAB 19:S$ = "Use the   or   key to choose a": GOSUB 100:S$ = "topic, or type a number (1-6).": GOSUB 100
  24. 930 S$ = "Then press RETURN.": GOSUB 100: PRINT :S$ = "* marks a topic you have finished.": GOSUB 100
  25. 940  HPLOT 93,150 TO 93,141 TO 94,141 TO 94,150: HPLOT 90,144 TO 94,141: HPLOT 97,144 TO 94,141
  26. 950  HPLOT 128,150 TO 128,141 TO 129,141 TO 129,150: HPLOT 125,147 TO 128,150: HPLOT 132,147 TO 129,150
  27. 970 :V% = 0
  28. 980  FOR I = 0 TO 5: IF  PEEK(791 +I)  THEN V% = V% +2: NEXT I
  29. 989  REM <CTRL-0x0a><CTRL-0x0a>** Turn on HIRES **<CTRL-0x0a>
  30. 990  POKE  -16297,0: POKE  -16302,0: POKE  -16304,0
  31. 999  REM <CTRL-0x0a><CTRL-0x0a>** Choose Option **<CTRL-0x0a>
  32. 1000 S$ = MENU$(V% +1): GOSUB 110
  33. 1010  IF  PEEK(KS%) <128  THEN 1010
  34. 1020 KEY% =  PEEK(KS%): POKE KC%,0
  35. 1100  IF KEY% = 138  THEN S$ = MENU$(V%): GOSUB 110:V% = V% +2: IF V% >10  THEN V% = 0
  36. 1120  IF KEY% = 139  THEN S$ = MENU$(V%): GOSUB 110:V% = V% -2: IF V% <0  THEN V% = 10
  37. 1130  IF KEY% >176  AND KEY% <183  THEN S$ = MENU$(V%): GOSUB 110:V% = (KEY% -177) *2: GOTO 1000
  38. 1199  REM <CTRL-0x0a><CTRL-0x0a>** Execute Choice **<CTRL-0x0a>
  39. 1200  IF KEY% < >141  THEN 1000
  40. 1202  PRINT CL$: HOME : TEXT 
  41. 1205  IF V%/2 = 5  THEN 2000
  42. 1210  VTAB 12:S$ = "Just a moment please...": GOSUB 100
  43. 1220  ON V%/2 +1 GOTO 1300,1305,1310,1320,1340
  44. 1300  PRINT D$"-INSIDE.INTRO"
  45. 1305  PRINT D$"-INSIDE.PROBLEM"
  46. 1310  PRINT D$"-INSIDE.STORY.H"
  47. 1320  PRINT D$"-INSIDE.STORY.S"
  48. 1340  PRINT D$"-TRIVIA.GAME"
  49. 1999  REM <CTRL-0x0a><CTRL-0x0a>** Quit Tutorial **<CTRL-0x0a>
  50. 2000  PRINT : PRINT D$"PREFIX /TUTOR/MENU"
  51. 2030  PRINT : PRINT D$"PREFIX /TUTOR/MENU"
  52. 2040  PRINT : PRINT D$"-/TUTOR/BASIC.SYSTEM"
  53. 8989  REM <CTRL-0x0a><CTRL-0x0a>** Choice Data **<CTRL-0x0a>
  54. 8990  DATA "1. Introduction "
  55. 8995  DATA "1.<INTRODUCTION>"
  56. 9000  DATA "2. The Problem at Hand "
  57. 9005  DATA "2.<THE PROBLEM AT HAND>"
  58. 9010  DATA "3. The Drama Unfolds "
  59. 9015  DATA "3.<THE DRAMA UNFOLDS>"
  60. 9020  DATA "4. The Plot Thickens "
  61. 9025  DATA "4.<THE PLOT THICKENS>"
  62. 9030  DATA "5. The Inside Story Game "
  63. 9035  DATA "5.<THE INSIDE STORY GAME>"
  64. 9040  DATA "6. Quit The Inside Story "
  65. 9050  DATA "6.<QUIT THE INSIDE STORY>"
  66. 9999  REM <CTRL-0x0a><CTRL-0x0a>** Error Handler **<CTRL-0x0a>
  67. 10000 ERR% =  PEEK(222): IF ERR% = 255  THEN  RESUME 
  68. 10020 LINE% =  PEEK(218) + PEEK(219) *256
  69. 10040  PRINT CL$: HOME : VTAB 5: PRINT "An ERROR has occurred in this program.": PRINT 
  70. 10100  IF ERR% = 6  THEN  PRINT MENU$(V%): PRINT "was not found on the diskette currently": PRINT "in the disk drive.  Make sure that you  have the right diskette:": PRINT "(Your Tour of the Apple II) in the": PRINT "disk drive.": GOTO 11000
  71. 10900  PRINT "The error does not seem to be one that": PRINT "this program knows about.  Please note": PRINT "the error number and line number listed": PRINT "below and report it to your dealer."
  72. 10910  PRINT : PRINT "Error Number = "ERR%: PRINT "Line Number  = "LINE%
  73. 10920  PRINT : PRINT "Please put another program diskette in": PRINT "the disk drive.  When you have done": PRINT "this press RETURN to continue."
  74. 10930  GOSUB 200: PRINT : PRINT D$"PR#5"
  75. 11000  PRINT : PRINT "Press RETURN to continue."
  76. 11020  GOSUB 200: RESUME 
  77. 11040  POKE KC%,0: RUN 
  78. 32998  REM <CTRL-0x0a><CTRL-0x0a>* By: Lance G. Saleme
  79. 32999  REM * COPYRIGHT 1984, 1982, 1988 APPLE COMPUTER, INC. *